El objetivo es representar gráficamente un número complejo y su conjugado en un sistema de ejes cartesianos, añadiendo: los 
nombres de los ejes, el número complejo, las componentes del complejo,  su módulo, su argumento y el complejo conjugado.

En primer lugar  definimos un número complejo y la línea que va desde cero a ese número complejo en un sistema cartesiano:

z=8+3I;

line1=Line[{{0,0},{Re[z],Im[z]}}];

point1={PointSize[.02],Point[{Re[z],Im[z]}]};

Show[Graphics[{line1, point1}, Axes->True]]

De igual manera, definimos el conjugado y su representación:

cz=Conjugate[z];
line2=Line[{{0,0},{Re[cz],Im[cz]}}];
point2={PointSize[.02],Point[{Re[cz],Im[cz]}]};
Show[Graphics[{line1, point1,line2,point2}, Axes->True]]

Lo siguiente es crear una línea de puntos indicando las componentes del número complejo. Para ello utilizamos la directiva Dashing 
a la línea deseada.

Definimos la componente horizontal y la vertical:

hline={Dashing[{0.04,0.04}], Line[{{0,Im[z]},{Re[z],Im[z]}}]};

vline={Dashing[{0.04,0.04}], Line[{{Re[z],0},{Re[z],Im[z]}}]};

Show[Graphics[{line1,point1,line2,point2,hline,vline}, 
      Axes->True, Ticks->{{{Re[z], "a"}},{{Im[z],"b"}}},
      AxesLabel->{Re,Im}, AspectRatio->Automatic]]

Queremos poner etiquetas a los números complejo y su conjugado, para ellos acudimos al elemento de texto: Text

Definimos los elementos que tienen que aparecer en el gráfico, así como su posición:

text1=Text[StyleForm["z = a+bi", {"Times-Italic",9}],{Re[z]-.75, Im[z]+.35}];
text2=Text[StyleForm["Abs [z]", {"Times-Italic",9}],{3.5, 2}];
text3=Text[StyleForm["Conjugate [z]= a-bi", {"Times-Italic",9}],{Re[cz]-1.4, Im[cz]-.35}];

Si lo combinamos todo:

Show[Graphics[{line1,line2,point1, point2,hline,vline, text1, text2, text3}, 
      Axes->True, Ticks->{{{Re[z], "a"}},{{Im[z],"b"}}},
      AxesLabel->{Re,Im}, AspectRatio->Automatic]]

Por último, necesitamos el arco del ángulo. Para ello recurrimos al elemento gráfico: Circle[{x, y}, r, {a, b}]

arc=Circle[{0,0},Abs[z]/3,{0,Arg[z]}];

text4= Text[StyleForm["Arg [z]",{"Times",9}],{3.5,.5}];

Show[Graphics[{line1,line2,point1, point2,hline,vline, text1, text2, text3, text4,arc}, 
      Axes->True, Ticks->{{{Re[z], "a"}},{{Im[z],"b"}}},
      AxesLabel->{Re,Im}, AspectRatio->Automatic]]